Need help compiling on manjaro

Software
38

This is what I do to compile and install:

Change to my darktable-git directory.
Inside I have this PKGBUILD file:

# Source: https://github.com/archlinux/svntogit-community/tree/master/darktable
# Maintainer: Bruno Pagani <archange@archlinux.org>
# Maintainer: Morten Linderud <foxboron@archlinux.org>
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Christian Himpel <chressie at gmail dot com>
# Contributor: Johannes Hanika <hanatos at gmail dot com>
# Contributor: Rafa García <hi at rafagarcia dot net>

pkgname=darktable-git
_gitname=darktable
epoch=2
pkgver=4.7.0.22
pkgrel=1
pkgdesc="Utility to organize and develop raw images"
arch=('i686' 'x86_64')
url="git+https://darktable.org"
license=(GPL3)
depends=(pugixml libjpeg-turbo colord-gtk libgphoto2 openexr lensfun iso-codes zlib
         exiv2 flickcurl openjpeg2 graphicsmagick lua osm-gps-map libsecret openmp
         gmic libavif)
optdepends=('dcraw: base curve script'
            'perl-image-exiftool: base curve script'
            'imagemagick: base curve and noise profile scripts'
            'ghostscript: noise profile script'
            'portmidi: game and midi controller input devices'
            'gnuplot: noise profile script')
makedepends=(git cmake intltool desktop-file-utils llvm clang portmidi python-jsonschema libwebp perl-pod-parser)
conflicts=(darktable)
provides=(darktable)
source=("git+https://github.com/darktable-org/darktable.git")
md5sums=('SKIP')

pkgver() {
    cd $_gitname
    git describe --long | sed 's/release-\(.*\)-\(.*\)-.*/\1.\2/' | sed 's/-/./g'
}

prepare() {
  cd $_gitname
#  git submodule init
  git config submodule.src/tests/integration.update none
  git submodule update --depth 1
  git submodule update --init --recursive
}

build() {
  cd $_gitname
  [[ ! -d build ]] && mkdir -p build
  cmake -B build \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_LIBDIR=/usr/lib \
        -DCMAKE_INSTALL_LIBEXECDIR=/usr/lib \
        -DCMAKE_BUILD_TYPE=Release \
        -DBINARY_PACKAGE_BUILD=1 \
        -DBUILD_USERMANUAL=False \
        -DUSE_LIBSECRET=ON \
        -DUSE_LUA=ON \
        -DUSE_COLORD=ON \
        -DBUILD_CURVE_TOOLS=ON \
        -DBUILD_NOISE_TOOLS=ON \
        -DRAWSPEED_ENABLE_LTO=ON \
        -DPROJECT_VERSION=${pkgver}
    make -j`grep -c '^processor' /proc/cpuinfo` -C build
}

package() {
  cd $_gitname
  make -C build DESTDIR=$pkgdir install
  ln -s darktable/libdarktable.so "${pkgdir}"/usr/lib/libdarktable.so
}

Then, to compile, create the package and install:

makepkg -scf 
sudo pacman -U darktable-git-...

If I want to directly compile, create the package and install, I use this one-liner:

makepkg -scfi

A little bit late as I see but anyway, I hope it helps you.

3 Likes