[Question] How to produce a timelapse with fixed stars and "moving" earth?

snibgo · November 15, 2019, 2:48pm

I used ImageMagick, with some Windows BAT scripts. The scripts do the chain search, (searching forwards and backwards from any frame), and do the alignment using IM’s “-distort”.

Making the “lightest” image (which I’ve realised you did, on another thread):

del lightest.miff

for %%F in (src\*.jpg) do (
  echo %%F

  if exist lightest.miff (
    %IMG7%magick ^
      lightest.miff ^
      %%F ^
      -compose Lighten -composite ^
      lightest.miff
  ) else (
    %IMG7%magick ^
      %%F ^
      lightest.miff
  )
)

%IMG7%magick ^
  lightest.miff ^
  lightest.jpg

For the movie, the overall process is:

call %PICTBAT%csFiles src\ DSCF*.JPG . venice

echo 722 834 >venice_features.lis
echo 3142 1809 >>venice_features.lis

set csSUPSAMP=4
set csDEBUG=1

call %PICTBAT%chainSrchMult venice venice_features.lis 25x15 51x31

md outframes

set venice.OutFrames=outframes\

call %PICTBAT%csaAlign venice

The two stars are at (722,834) and (3142,1809) in the first frame. I chose to align all frames after the first to the first frame. I could have chosen instead to align to a central frame, or the final frame, or whatever.

Now we have the distorted and aligned frames. For the movie, we make smaller JPEGs, numbered from 0000:

set I=0
for %%F in (outframes\DSCF*.MIFF) do (
  echo %%F

  set LZ=000000!I!
  set LZ=!LZ:~-4!

  rem copy /Y %%F %%~dpFforffm_!LZ!.jpg

  %IMG7%magick %%F -resize 600 %%~dpFforffm_!LZ!.jpg

  set /A I+=1
)

From those JPEGs, make the movie:

ffmpeg -ioutframes\forffm_%%04d.jpg venice.mp4

The BAT scripts are part of a larger package for performing and using chain searches. I haven’t yet written this up. Meanwhile, here is a zip of the scripts used here:
http://snibgo.com/imforums/cs_bats.zip

Here are three full-size distorted frames (1725, 1825 and 1935), so the two stars align: