Can GIMP/G'MIC do a star effect?


#1

I would like to know if G’MIC and GIMP can do glare effect similar to Blender Glare filter?
I have found that G’MIC bloom filter produce something similar, but I cannot make it do more than 4 steaks.
The last mention of glare effect I can find is this:


#2

If you look at photo taken from hubble telescope you can see this effect.


(Javi Ballester) #3

Hi Kevin. Maybe Gimp Filters>Light and Shadow>Sparkle or Gmic Testing>Iain Fergusson>Iain Star Burst.


#4

Cannot be done without a proper scene referred model. Display referred glares, blooms, flares, etc. are all hacks.


#5

Don’t really understand but I believe it is just multiple bilateral blur that rotate.


(Javi Ballester) #6
+fx_blur_bloom 1,4,4,0,0,0,1,10,7,0			# Apply 'Blur [bloom]' angle=10
+fx_blur_bloom[0] 1,4,4,0,0,0,1,70,7,0		# Apply 'Blur [bloom]' angle=70
+fx_blur_bloom[0] 1,4,4,0,0,0,1,130,7,0		# Apply 'Blur [bloom]' angle=130
rm[0]										# Remove original
blend[-1,-2] screen							# Blend two last images with screen blending-mode
blend[-1,-2] screen							# Blend two last images with screen blending-mode


(Javi Ballester) #7

I’ve modified Blur [bloom] to Blur [bloom_glare] and added axis and opacity options:

#@gui Blur [bloom_glare] : fx_blur_bloom_glare, fx_blur_bloom_glare_preview(0)
#@gui : Amplitude = float(1,0,10)
#@gui : Ratio = float(2,0,5)
#@gui : Iterations = int(5,0,100)
#@gui : Operator = choice("Add","Max","Min")
#@gui : Kernel = choice("Quasi-gaussian","Gaussian","Box","Triangle","Quadratic")
#@gui : Normalize scales = bool(0)
#@gui : Anisotropy = bool(0,0,1)
#@gui : Angle = float(0,0,180)
#@gui : Axis = int(1,1,10)
#@gui : Opacity = float(0.5,0,1)
#@gui : note = note("Parameters <i>Angle</i>, <i>Axis</i> and <i>Opacity</i> are only active when <i>Anisotropy</i> is checked")
#@gui : sep = separator()
#@gui : Channel(s) = choice(7,"All","RGBA [all]","RGB [all]","RGB [red]","RGB [green]","RGB [blue]","RGBA [alpha]","Linear RGB [all]","Linear RGB [red]","Linear RGB [green]","Linear RGB [blue]","YCbCr [luminance]","YCbCr [blue-red chrominances]","YCbCr [blue chrominance]","YCbCr [red chrominance]","YCbCr [green chrominance]","Lab [lightness]","Lab [ab-chrominances]","Lab [a-chrominance]","Lab [b-chrominance]","Lch [ch-chrominances]","Lch [c-chrominance]","Lch [h-chrominance]","HSV [hue]","HSV [saturation]","HSV [value]","HSI [intensity]","HSL [lightness]","CMYK [cyan]","CMYK [magenta]","CMYK [yellow]","CMYK [key]","YIQ [luma]","YIQ [chromas]")
#@gui : sep = separator() 
#@gui : Preview type = choice("Full","Forward horizontal","Forward vertical","Backward horizontal","Backward vertical","Duplicate top","Duplicate left","Duplicate bottom","Duplicate right")
#@gui : sep = separator(), note = note("<small>Author: <i><a href="https://goo.gl/Ryf7Cv">David Tschumperl&#233;</a></i>.      Latest update: <i>2015/03/02</i>.</small>")
fx_blur_bloom_glare :
op=${"arg 1+$4,+,max,min"}
if {!$7} 
	ac "blur_bloom ${1-3},"$op",${5-6},xy",$11
else
	wh={[w,h]}
	repeat $9
		ang={(180/$9)*($>)+$8}
		+rotate[0] $ang,2,1
		ac. "blur_bloom ${1-3},"$op",${5-6},x",$11
		rotate. {-$ang},2,1
		r. $wh,1,100%,0,0,0.5,0.5 
		c. 0,255
	done
	repeat {$9}								
		blend[0,-1] screen,$10
	done
fi
fx_blur_bloom_glare_preview :
gui_split_preview "fx_blur_bloom_glare $*",$-1


#8

Hey, thanks. Will this be include in official G’MIC?


(Javi Ballester) #9

Don’t know the process to include the modified filter by default but you can use it creating a text file in your home folder, naming it “.gmic”, pasting the code inside and reloading filters in gimp-gmic plugin.
More info here.


#10

@kevin_tee The effect is just multiple applications of blur_bloom.

We could ask @David_Tschumperle to add this feature to blur_bloom.


(Alex) #11

There already is bloom effect with rotation option, you’ve got to apply several times with anisotropy effect enabled.